I2C Scanner / Finder
If your 1602 is only showing solid blocks in the top row or both rows, chances are, you are referencing the wrong address. This handy sketch will give you all the active addresses hooked up to your Arduino.

// --------------------------------------
// i2c_scanner
//
// Version 1
//    This program (or code that looks like it)
//    can be found in many places.
//    For example on the Arduino.cc forum.
//    The original author is not know.
// Version 2, Juni 2012, Using Arduino 1.0.1
//     Adapted to be as simple as possible by Arduino.cc user Krodal
// Version 3, Feb 26  2013
//    V3 by louarnold
// Version 4, March 3, 2013, Using Arduino 1.0.3
//    by Arduino.cc user Krodal.
//    Changes by louarnold removed.
//    Scanning addresses changed from 0...127 to 1...119,
//    according to the i2c scanner by Nick Gammon
//    http://www.gammon.com.au/forum/?id=10896
// Version 5, March 28, 2013
//    As version 4, but address scans now to 127.
//    A sensor seems to use address 120.
//
// Version 6, November 14, 2013
//    revised to run in the loop() function more
//    like robsoles thought it should.
//
// This sketch tests the standard 7-bit addresses
// Devices with higher bit address might not be seen properly.
//

#include <Wire.h>

volatile byte error, address;
volatile int nDevices;
volatile long passes;

void setup()
{
  Wire.begin();

  Serial.begin(9600);
  Serial.println("\nI2C Scanner");
}


void loop()
{
  switch(address) {
  case 0:
    Serial.print("Scanning[");
    Serial.print(passes++,DEC);
    Serial.println("]...");
    nDevices = 0;
  break;
  case 128: // finished scanning, show results
    if (nDevices == 0)
      Serial.println("No I2C devices found\n");
    else
      Serial.println("done\n");
  break;
  default:
    if(address<128) {
      Wire.beginTransmission(address);
      error = Wire.endTransmission();
      if (error == 0)
      {
        Serial.print("I2C device found at address 0x");
        if (address<16)
          Serial.print("0");
        Serial.print(address,HEX);
        Serial.println("  !");
        nDevices++;
      }
      else if (error==4)
      {
        Serial.print("Unknown error at address 0x");
        if (address<16)
          Serial.print("0");
        Serial.println(address,HEX);
      }
    } else {
      delay(40); // about 5 seconds after all the looping.
    }
  }
  address++; // naturally overflows back to 0
}


    

Warning: require_once(../httpdocs/QuickDRY/utilities/Log.php): failed to open stream: No such file or directory in G:\RetroLCD.com\httpdocs\QuickDRY\QuickDRY.php on line 201

Fatal error: require_once(): Failed opening required '../httpdocs/QuickDRY/utilities/Log.php' (include_path='.;C:\php\pear') in G:\RetroLCD.com\httpdocs\QuickDRY\QuickDRY.php on line 201